Utilities Professional 1-1500/Utilities Professional 1-1500 (1994)(WPD)[!].iso/12511500/var1373.dms/var1373.adf/MM Hard Disk Install

Text File | 1993-11-08 | 5KB | 229 lines

; $VER: Money Matters v3.22/10/93
; Copyright (C) Digita International

(complete 0)


; The amount of space needed on the hard disk to install
(set HDSizeNeeded 1)


; Start string definitions
(set #ProgName
(cat "Money Matters"
))


(set #Welcome-Pirate
(cat "\n\n\n\nWelcome to the " #ProgName " Installer\n\n"
    "Copyright (C) 1993 Digita International\n\n\n\n"
))

(set #InsertDiskMsg
(cat "\nPlease insert the disk labelled\n\n"
))

(set #InsertAmigaDiskMsg
(cat "\nPlease insert the Amiga Workbench disk labelled\n\n"
))

(set #diskhelp
    (cat "\n    If you know that the correct disk is in the drive, but you still cannot proceed, "
        "then the name of the disk is incorrect.\n"
        "    Ensure that the disk name is not preceded by 'copy_of_', or blank spaces before or after the disk name.\n\n\n" @askdisk-help
    )
)

(set #MMDiskName
(cat "Money Matters"
))


(set #BadKick
(cat #LongProgName " requires Workbench 2.04 or above to work correctly."
))


(set #HardDiskDefaultDest
(cat "Work:"
))

(set #LibSource
(cat #MMDiskName ":Libs"
))

(set #FontSource
(cat #MMDiskName ":Fonts"
))


(set #HardDiskLibDest
(cat "LIBS:"
))

(set #HardDiskFontDest
(cat "FONTS:"
))


(set #HardDiskDestChoiceMsg
(cat "Where do you want to install the\n" #ProgName " program drawer?"
))

(set #HardDiskDestChoiceHelp
(cat "    Select the drawer where you want to install " #ProgName ", then click Proceed (a new drawer titled \"" #ProgName "\" will be created and will contain the " #ProgName " program.)"
))

(set #HardDiskDestChoiceConfirmMsg1
(cat "\nAre you sure you want to install " #ProgName " in the destination:\n\n\""
))

(set #HardDiskDestChoiceConfirmMsg2
(cat "\"\n\n\n\n(A new drawer titled \"Money Matters\" will be created and this will contain the " #ProgName " program.)"
))

(set #HardDiskDestChoiceConfirmHelp
(cat "    Click YES to keep the destination drawer.\n\n    Click NO if you want to change the destination drawer."
))

(set #DrawerExistsMsg
(cat "\nA drawer titled \"Money Matters\" already exists in the destination you have chosen.\n\nDo you wish to replace it or choose a new destination?"
))

(set #DrawerExistsChoice1
(cat "Replace it"
))

(set #DrawerExistsChoice2
(cat "Choose new destination"
))

(set #DrawerExistsHelp
(cat "\n    You have chosen a destination drawer which already has \"Money Matters\" installed there.\n\n    Click \"" #DrawerExistsChoice1 "\" to replace the contents with this new version of " #ProgName ".\n    Click \"" #DrawerExistsChoice2 "\" to choose a new destination drawer."
))

(set #NoDiskSpaceMsg
(cat "There is insufficient available space on your hard disk to install " #ProgName ". You will need at least " HDSizeNeeded "MB of free space.\n\nEither Abort this installation and delete some files from your hard disk, or try a different partition on your hard disk."
))

(set #HardDiskWorkingMsg
(cat "Please wait... Installation is proceeding."
))


(set #ImportantFinishedMsg
(cat "\nI M P O R T A N T\n\n\nDon't forget to fill out your prepaid registration card and send it back to us.\n\nOnly registered users can receive technical support (via phone or letter), special upgrade deals and discounts."
))


; INSTALLATION
(message #Welcome-Pirate)


(if (< (/ (getversion) 65536) 37)
    ( abort #badkick )
)

;INSTALL ON HARD DISK
(
    (complete 10)
    (set MyDefault #HardDiskDefaultDest)
    (set LibDest #HardDiskLibDest)
    (set OK 0)
    (until (= OK 1)
        (set DestPath
            (askdir
                (prompt #HardDiskDestChoiceMsg)
                (help #HardDiskDestChoiceHelp)
                (default MyDefault)
            )
        )
            (if (exists (tackon DestPath "Money Matters")) ; if there is already a drawer named Money Matters
                (
                    (if
                        (askbool
                            (prompt #DrawerExistsMsg)
                            (choices #DrawerExistsChoice1 #DrawerExistsChoice2)
                            (help #DrawerExistsHelp)
                            (default 0)
                        )
                        ( ; [true] Lets replace it
                            (set OK 1)
                        )
                        ( ;else [false]
                            (set OK 0)
                        )
                    )
                )
                (    ;else
                    (if
                        (askbool
                            (prompt #HardDiskDestChoiceConfirmMsg1 DestPath #HardDiskDestChoiceConfirmMsg2)
                            (help #HardDiskDestChoiceConfirmHelp)
                        )
                        (set OK 1)
                    ) ;endif
                ) ;end else
            ) ;endif
        (if (= OK 1)
            (
                ; Multiply MB by 1024 twice to get number of bytes
                (set SpaceNeeded (* (* HDSizeNeeded 1024) 1024))
                (if (< (getdiskspace DestPath) SpaceNeeded)
                    (
                        (message #NoDiskSpaceMsg)
                        (set OK 0)
                    )
                ) ;endif
            )
        ) ;endif
    ) ;end until

    (complete 20)
    (set MMDrawerDest (tackon DestPath #ProgName))

    ; Okay to copy files
    (makedir MMDrawerDest)
    (complete 30)
    (askdisk
        (prompt #InsertDiskMsg #MMDiskName)
        (help #diskhelp)
        (dest #MMDiskName)
    )
    (working
        (prompt #HardDiskWorkingMsg)
    )
    (copyfiles
        (source (cat #MMDiskName ":Money Matters"))
        (dest MMDrawerDest)
        (infos)
        (all)
    )
    (complete 85)

    (copyfiles
        (source #FontSource)
        (dest #HardDiskFontDest)
        (pattern "Pica60")
        (fonts)
        (optional "force")
    )

    (complete 90)
    (if (not (exists (tackon #HardDiskLibDest "asl.library")))
        (
            (copyfiles
                (source #LibSource)
                (dest #HardDiskLibDest)
                (pattern "asl.library")
                (optional "force")            ; ignore delete protection
            )
            (complete 95)
        )
    )
    (set @default-dest DestPath)
) ;end InstallHD

(complete 100)
(message #ImportantFinishedMsg)
(exit)